mirror of
https://gitlab.nic.cz/labs/bird.git
synced 2025-03-11 17:08:46 +00:00
064b59d1c7
When you redefine a keyword, a warning is issued. It is recommended to abstain from redefining keywords as it may yield lots of strange parse errors in config. It is not possible to use a keyword as a protocol or template name due to collisions in config language.
65 lines
1.6 KiB
Plaintext
65 lines
1.6 KiB
Plaintext
m4_divert(-1)m4_dnl
|
|
#
|
|
# BIRD -- Generator of Configuration Grammar
|
|
#
|
|
# (c) 1998--1999 Martin Mares <mj@atrey.karlin.mff.cuni.cz>
|
|
#
|
|
# Can be freely distributed and used under the terms of the GNU GPL.
|
|
#
|
|
|
|
# Diversions used:
|
|
# 1 includes
|
|
# 2 types etc.
|
|
# 3 rules
|
|
# 4 C code
|
|
|
|
# Common aliases
|
|
m4_define(DNL, `m4_dnl')
|
|
|
|
# Define macros for defining sections
|
|
m4_define(CF_ZONE, `m4_divert($1)/* $2 from m4___file__ */')
|
|
m4_define(CF_HDR, `CF_ZONE(1, Headers)')
|
|
m4_define(CF_DEFINES, `CF_ZONE(1, Defines)')
|
|
m4_define(CF_DECLS, `CF_ZONE(2, Declarations)')
|
|
m4_define(CF_GRAMMAR, `CF_ZONE(3, Grammar)')
|
|
m4_define(CF_CODE, `CF_ZONE(4, C Code)')
|
|
m4_define(CF_END, `m4_divert(-1)')
|
|
|
|
# Keywords act as a %token <kw> + added to a keyword: rule
|
|
m4_define(CF_KEYWORDS, `m4_ifelse($#,1,,[[CF_KEYWORDS(m4_shift($@))]])DNL
|
|
m4_ifdef([[CF_tok_$1]],,[[m4_define([[CF_tok_$1]],1)m4_divert(2)%token <kw> $1
|
|
m4_divert(3)keyword: $1 ;
|
|
m4_divert(2)]])')
|
|
|
|
# CLI commands
|
|
m4_define(CF_CLI, `m4_define([[CF_cmd]], cmd_[[]]m4_translit($1, [[ ]], _))DNL
|
|
m4_divert(2)CF_KEYWORDS(m4_translit($1, [[ ]], [[,]]))
|
|
m4_divert(3)cli_cmd: CF_cmd
|
|
CF_cmd: $1 $2 END')
|
|
m4_define(CF_CLI_CMD, `')
|
|
m4_define(CF_CLI_HELP, `')
|
|
|
|
# ENUM declarations are ignored
|
|
m4_define(CF_ENUM, `')
|
|
m4_define(CF_ENUM_PX, `')
|
|
|
|
# After all configuration templates end, we finally generate the grammar file.
|
|
m4_m4wrap(`
|
|
m4_divert(0)DNL
|
|
%{
|
|
m4_undivert(1)DNL
|
|
%}
|
|
|
|
m4_undivert(2)DNL
|
|
|
|
%%
|
|
m4_undivert(3)DNL
|
|
|
|
%%
|
|
m4_undivert(4)DNL
|
|
')
|
|
|
|
# As we are processing C source, we must access all M4 primitives via
|
|
# m4_* and also set different quoting convention: `[[' and ']]'
|
|
m4_changequote([[,]])
|