mirror of
https://gitlab.nic.cz/labs/bird.git
synced 2024-11-18 09:08:42 +00:00
33 lines
1.3 KiB
Plaintext
33 lines
1.3 KiB
Plaintext
m4_divert(-1)m4_dnl
|
|
#
|
|
# BIRD -- Generator of Configuration Keyword List
|
|
#
|
|
# (c) 1998--1999 Martin Mares <mj@atrey.karlin.mff.cuni.cz>
|
|
#
|
|
# Can be freely distributed and used under the terms of the GNU GPL.
|
|
#
|
|
|
|
# Simple iterator
|
|
m4_define(CF_itera, `m4_ifelse($#, 1, [[CF_iter($1)]], [[CF_iter($1)[[]]CF_itera(m4_shift($@))]])')
|
|
m4_define(CF_iterate, `m4_define([[CF_iter]], m4_defn([[$1]]))CF_itera($2)')
|
|
|
|
# Keywords are translated to C initializers
|
|
m4_define(CF_handle_kw, `m4_divert(0){ "m4_translit($1,[[A-Z]],[[a-z]])", $1 },
|
|
m4_divert(-1)')
|
|
m4_define(CF_keywd, `m4_ifdef([[CF_tok_$1]],,[[m4_define([[CF_tok_$1]],1)CF_handle_kw($1)]])')
|
|
m4_define(CF_KEYWORDS, `m4_define([[CF_toks]],[[]])CF_iterate([[CF_keywd]], [[$@]])m4_ifelse(CF_toks,,,%token[[]]CF_toks
|
|
)DNL')
|
|
|
|
# CLI commands generate keywords as well
|
|
m4_define(CF_CLI, `CF_KEYWORDS(m4_translit($1, [[ ]], [[,]]))
|
|
')
|
|
|
|
# Enums are translated to C initializers: use CF_ENUM(typename, prefix, values)
|
|
m4_define(CF_enum, `m4_divert(0){ "CF_enum_prefix[[]]$1", -((CF_enum_type<<16) | CF_enum_prefix[[]]$1) },
|
|
m4_divert(-1)')
|
|
m4_define(CF_ENUM, `m4_define([[CF_enum_type]],$1)m4_define([[CF_enum_prefix]],$2)CF_iterate([[CF_enum]], [[m4_shift(m4_shift($@))]])DNL')
|
|
|
|
# As we are processing C source, we must access all M4 primitives via
|
|
# m4_* and also set different quoting convention: `[[' and ']]'
|
|
m4_changequote([[,]])
|